CLS
PRINT "Wandelt den Foehr Kalender in Eingabe fuer VCS um."
PRINT "Foehr Kalender als Text abspeichern. "
OPEN "I", 1, "foehr.txt"
OPEN "O", 2, "foehr.out"
OPEN "O", 3, "foehr.vcs"
PRINT #3, "BEGIN:VCALENDAR"
PRINT #3, "VERSION:1.0"
stz$ = ".,!:;?-+"
DO
  LINE INPUT #1, zeile$
  zeile$ = LTRIM$(RTRIM$(zeile$))
  '
  ' Datum suchen.
  IF MID$(zeile$, 5, 1) = "-" THEN
    IF MID$(zeile$, 8, 1) = "-" THEN
      IF MID$(zeile$, 11, 1) = " " THEN
        jahr$ = MID$(zeile$, 1, 4)
        monat$ = MID$(zeile$, 6, 2)
        tag$ = MID$(zeile$, 9, 2)
        LINE INPUT #1, Titel$
        Titel$ = LTRIM$(RTRIM$(Titel$))
        '
        ' Bis Uhrzeit.
        desc$ = ""
        uhr$ = ""
        DO
          LINE INPUT #1, zeile$
          zeile$ = LTRIM$(RTRIM$(zeile$))
          IF LEFT$(zeile$, 3) = "Ab " THEN
            uhr$ = MID$(zeile$, 4)
            uhr$ = LEFT$(uhr$, INSTR(uhr$ + " ", " ") - 1)
            IF MID$(uhr$, 3, 1) = ":" THEN
              stunde$ = MID$(uhr$, 1, 2)
              minute$ = MID$(uhr$, 4, 2)
              sekunde$ = "00"
            END IF
          ELSE
            desc$ = desc$ + zeile$
            IF INSTR(stz$, RIGHT$(zeile$, 1)) = 0 THEN
              desc$ = desc$ + " "
            ELSE
              desc$ = desc$ + " "
            END IF
          END IF
        LOOP UNTIL uhr$ <> ""
        desc$ = LTRIM$(desc$)
        IF desc$ <> SPACE$(LEN(desc$)) THEN desc$ = RTRIM$(desc$) + ". "
        IF RIGHT$(desc$, 3) = ".. " THEN desc$ = LEFT$(desc$, LEN(desc$) - 2) + " "
        '
        ' Bis Leerzeile
        DO
          LINE INPUT #1, zeile$
          zeile$ = LTRIM$(RTRIM$(zeile$))
          IF zeile$ <> "Kosten / Eintritt:" THEN
            IF zeile$ <> "" THEN
              desc$ = desc$ + zeile$
              IF LEFT$(zeile$, 5) = "Ort: " THEN
                desc$ = desc$ + ". "
              ELSE
                desc$ = desc$ + " "
              END IF
            END IF
          END IF
        LOOP UNTIL zeile$ = ""
        desc$ = LTRIM$(RTRIM$(desc$) + ".")
        IF RIGHT$(desc$, 2) = ".." THEN desc$ = LEFT$(desc$, LEN(desc$) - 1)
        PRINT jahr$ + monat$ + tag$ + stunde$ + minute$ + sekunde$ + " " + Titel$
        'PRINT LEFT$(desc$, 79)
        'PRINT RIGHT$(desc$, 79)
        PRINT #2, "====="
        PRINT #2, "Summary: " + Titel$
        PRINT #2, "Description: " + desc$
        PRINT #2, "Jahr: " + jahr$
        PRINT #2, "Monat: " + monat$
        PRINT #2, "Tag: " + tag$
        PRINT #2, "Stunde: " + stunde$
        PRINT #2, "Minute: " + minute$
        PRINT #2, "Sekunde: " + sekunde$
        PRINT #3, "BEGIN:VEVENT"
        PRINT #3, "SUMMARY:" + Titel$
        PRINT #3, "DESCRIPTION:" + desc$
        stunden$ = RIGHT$("00" + MID$(STR$(VAL(stunde$) + 2), 2), 2)
        PRINT #3, "DTSTART:" + jahr$ + monat$ + tag$ + "T" + stunde$ + minute$ + sekunde$ + "Z"
        PRINT #3, "DTEND:" + jahr$ + monat$ + tag$ + "T" + stunden$ + minute$ + sekunde$ + "Z"
        PRINT #3, "UID:" + "Foehr-" + jahr$ + "-" + monat$ + "-" + tag$ + "-" + stunde$ + "-" + Titel$
        PRINT #3, "END:VEVENT"
      END IF
    END IF
  END IF
LOOP UNTIL EOF(1)
PRINT #3, "END:VCALENDAR"
CLOSE